diff mbox series

[meta-dpdk] dpdk: upgrade to 25.11

Message ID 20251216024301.2972678-1-ruiqiang.hao@windriver.com
State New
Headers show
Series [meta-dpdk] dpdk: upgrade to 25.11 | expand

Commit Message

Ruiqiang Hao Dec. 16, 2025, 2:43 a.m. UTC 
From: Ruiqiang Hao <Ruiqiang.Hao@windriver.com>

Upgrade to dpdk 25.11 release.

Signed-off-by: Ruiqiang Hao <Ruiqiang.Hao@windriver.com>
---
 recipes-extended/dpdk/dpdk_25.11.0.bb | 71 +++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 recipes-extended/dpdk/dpdk_25.11.0.bb
diff mbox series

Patch

diff --git a/recipes-extended/dpdk/dpdk_25.11.0.bb b/recipes-extended/dpdk/dpdk_25.11.0.bb
new file mode 100644
index 0000000..eb3a0d4
--- /dev/null
+++ b/recipes-extended/dpdk/dpdk_25.11.0.bb
@@ -0,0 +1,71 @@ 
+include dpdk.inc
+
+SRC_URI += " file://0001-config-meson-get-cpu_instruction_set-from-meson-opti.patch"
+
+STABLE = "-stable"
+BRANCH = "v25.11"
+SRCREV = "ed957165eadbe60a47d5ec223578cdd1c13d0bd9"
+S = "${WORKDIR}/git"
+
+def get_cpu_instruction_set(bb, d):
+    import re
+    march = re.search(r'-march=([^\s]*)', d.getVar('CC'))
+    if march:
+        return march.group(1)
+    else:
+        return "core2"
+
+EXTRA_OEMESON = " -Dexamples=all -Dcpu_instruction_set=${@get_cpu_instruction_set(bb, d)} "
+
+COMPATIBLE_MACHINE = "null"
+COMPATIBLE_HOST:libc-musl:class-target = "null"
+COMPATIBLE_HOST:linux-gnux32 = "null"
+
+PACKAGECONFIG ??= " "
+PACKAGECONFIG[afxdp] = ",,libbpf xdp-tools"
+PACKAGECONFIG[libvirt] = ",,libvirt"
+
+RDEPENDS:${PN} += "pciutils python3-core"
+RDEPENDS:${PN}-examples += "bash"
+DEPENDS = "numactl python3-pyelftools-native"
+
+inherit meson pkgconfig
+
+INSTALL_PATH = "${prefix}/share/dpdk"
+
+do_install:append(){
+    # remove  source files
+    rm -rf ${D}/${INSTALL_PATH}/examples/*
+
+    # Install examples
+    install -m 0755 -d ${D}/${INSTALL_PATH}/examples/
+    for dirname in ${B}/examples/dpdk-*
+    do
+        if [ ! -d ${dirname} ] && [ -x ${dirname} ]; then
+            install -m 0755 ${dirname} ${D}/${INSTALL_PATH}/examples/
+        fi
+    done
+
+}
+
+PACKAGES =+ "${PN}-examples ${PN}-tools"
+
+FILES:${PN} += " ${bindir}/dpdk-testpmd \
+		 ${bindir}/dpdk-proc-info \
+		 ${libdir}/*.so* \
+		 ${libdir}/dpdk/pmds-26.0/*.so* \
+		 "
+FILES:${PN}-examples = " \
+	${prefix}/share/dpdk/examples/* \
+	"
+
+FILES:${PN}-tools = " \
+    ${bindir}/dpdk-pdump \
+    ${bindir}/dpdk-test \
+    ${bindir}/dpdk-test-* \
+    ${bindir}/dpdk-*.py \
+    "
+
+CVE_PRODUCT = "data_plane_development_kit"
+
+INSANE_SKIP:${PN} = "dev-so"