diff mbox series

[meta-arago,scarthgap,14/14] netopeer2-server: move and clean up

Message ID 20250317183724.31563-16-reatmon@ti.com
State Accepted
Delegated to: Ryan Eatmon
Headers show
Series Update and cleanup sysrepo packages | expand

Commit Message

Ryan Eatmon March 17, 2025, 6:37 p.m. UTC 
From: Denys Dmytriyenko <denys@konsulko.com>

* Move into recipes-extended
* Combine with bbappend
* Shorten SUMMARY, split DESCRIPTION
* Update DEPENDS - remove systemd and add sysrepo-native
* Don't hardcode /usr when passing to CMake
* Also pass -DSYSREPO_SETUP=OFF to CMake
* Update installing scripts - remove user/group, add permissions

Signed-off-by: Denys Dmytriyenko <denys@konsulko.com>
Signed-off-by: Ryan Eatmon <reatmon@ti.com>
---
 .../0001-Add-EST-Yang-Models.patch            |  0
 .../netopeer2-server/netopeer2-server         |  0
 .../netopeer2-serverd.service                 |  0
 .../sysrepo/netopeer2-server_git.bb           | 53 +++++++++++++++++++
 .../netopeer2-server/netopeer2-server_git.bb  | 47 ----------------
 .../netopeer2-server_git.bbappend             |  5 --
 6 files changed, 53 insertions(+), 52 deletions(-)
 rename meta-arago-extras/{recipes-sysrepo/netopeer2-server => recipes-extended/sysrepo}/netopeer2-server/0001-Add-EST-Yang-Models.patch (100%)
 rename meta-arago-extras/{recipes-sysrepo/netopeer2-server => recipes-extended/sysrepo}/netopeer2-server/netopeer2-server (100%)
 rename meta-arago-extras/{recipes-sysrepo/netopeer2-server => recipes-extended/sysrepo}/netopeer2-server/netopeer2-serverd.service (100%)
 create mode 100644 meta-arago-extras/recipes-extended/sysrepo/netopeer2-server_git.bb
 delete mode 100644 meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server_git.bb
 delete mode 100644 meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server_git.bbappend
diff mbox series

Patch

diff --git a/meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server/0001-Add-EST-Yang-Models.patch b/meta-arago-extras/recipes-extended/sysrepo/netopeer2-server/0001-Add-EST-Yang-Models.patch
similarity index 100%
rename from meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server/0001-Add-EST-Yang-Models.patch
rename to meta-arago-extras/recipes-extended/sysrepo/netopeer2-server/0001-Add-EST-Yang-Models.patch
diff --git a/meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server/netopeer2-server b/meta-arago-extras/recipes-extended/sysrepo/netopeer2-server/netopeer2-server
similarity index 100%
rename from meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server/netopeer2-server
rename to meta-arago-extras/recipes-extended/sysrepo/netopeer2-server/netopeer2-server
diff --git a/meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server/netopeer2-serverd.service b/meta-arago-extras/recipes-extended/sysrepo/netopeer2-server/netopeer2-serverd.service
similarity index 100%
rename from meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server/netopeer2-serverd.service
rename to meta-arago-extras/recipes-extended/sysrepo/netopeer2-server/netopeer2-serverd.service
diff --git a/meta-arago-extras/recipes-extended/sysrepo/netopeer2-server_git.bb b/meta-arago-extras/recipes-extended/sysrepo/netopeer2-server_git.bb
new file mode 100644
index 00000000..a704897f
--- /dev/null
+++ b/meta-arago-extras/recipes-extended/sysrepo/netopeer2-server_git.bb
@@ -0,0 +1,53 @@ 
+SUMMARY = "Implementation of network configuration tools based on NETCONF Protocol"
+DESCRIPTION = "Netopeer2 is based on the new generation of the NETCONF and YANG libraries - \
+libyang and libnetconf2. The Netopeer server uses sysrepo as a NETCONF datastore implementation."
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=41daedff0b24958b2eba4f9086d782e1"
+
+SRC_URI = " \
+    git://github.com/CESNET/Netopeer2.git;protocol=https;branch=master \
+    file://0001-Add-EST-Yang-Models.patch \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'file://netopeer2-server', '', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'file://netopeer2-serverd.service', '', d)} \
+"
+
+PV = "2.2.35+git"
+SRCREV = "6d1cb61ef3ce2274a91dc9cbc51318bcd0b54697"
+
+S = "${WORKDIR}/git"
+
+DEPENDS = "libyang libnetconf2 sysrepo sysrepo-native"
+RDEPENDS:${PN} += "bash curl"
+
+FILES:${PN} += "${datadir}/yang* ${datadir}/netopeer2/* ${libdir}/sysrepo-plugind/*"
+
+inherit cmake pkgconfig
+inherit ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)}
+
+EXTRA_OECMAKE = " \
+    -DCMAKE_INSTALL_PREFIX=${prefix} \
+    -DCMAKE_BUILD_TYPE:String=Release \
+    -DSYSREPO_SETUP=OFF \
+    -DINSTALL_MODULES=OFF \
+    -DGENERATE_HOSTKEY=OFF \
+    -DMERGE_LISTEN_CONFIG=OFF \
+"
+
+SYSTEMD_PACKAGES = "${PN}"
+SYSTEMD_SERVICE:${PN} = "netopeer2-serverd.service"
+SYSTEMD_AUTO_ENABLE:${PN} = "disable"
+
+do_install:append () {
+    install -d ${D}${sysconfdir}/netopeer2/scripts
+    install -m 0755 ${S}/scripts/setup.sh ${D}${sysconfdir}/netopeer2/scripts/setup.sh
+    install -m 0755 ${S}/scripts/merge_hostkey.sh ${D}${sysconfdir}/netopeer2/scripts/merge_hostkey.sh
+    install -m 0755 ${S}/scripts/merge_config.sh ${D}${sysconfdir}/netopeer2/scripts/merge_config.sh
+    if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
+        install -d ${D}${sysconfdir}/init.d
+        install -m 0755 ${WORKDIR}/netopeer2-server ${D}${sysconfdir}/init.d/
+    fi
+    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+        install -d ${D}${systemd_system_unitdir}
+        install -m 0644 ${WORKDIR}/netopeer2-serverd.service ${D}${systemd_system_unitdir}
+    fi
+}
diff --git a/meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server_git.bb b/meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server_git.bb
deleted file mode 100644
index 21bc9a03..00000000
--- a/meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server_git.bb
+++ /dev/null
@@ -1,47 +0,0 @@ 
-SUMMARY = "Netopeer2 is a set of tools implementing network configuration tools based on the NETCONF Protocol."
-DESCRIPTION = "Netopeer2 is based on the new generation of the NETCONF and YANG libraries - libyang and libnetconf2. The Netopeer server uses sysrepo as a NETCONF datastore implementation."
-LICENSE = "BSD-3-Clause"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=41daedff0b24958b2eba4f9086d782e1"
-
-SRC_URI = "git://github.com/CESNET/Netopeer2.git;protocol=https;branch=master \
-          ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', \
-	        'file://netopeer2-server', '', d)} \
-          ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', \
-	        'file://netopeer2-serverd.service', '', d)} \
-          "
-
-PV = "2.2.35+git"
-SRCREV = "6d1cb61ef3ce2274a91dc9cbc51318bcd0b54697"
-
-S = "${WORKDIR}/git"
-
-DEPENDS = "libyang libnetconf2 sysrepo systemd"
-RDEPENDS:${PN} += "bash curl"
-
-FILES:${PN} += "${datadir}/yang* ${datadir}/netopeer2/* ${libdir}/sysrepo-plugind/*"
-
-inherit cmake pkgconfig
-inherit ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)}
-
-# Specify any options you want to pass to cmake using EXTRA_OECMAKE:
-EXTRA_OECMAKE = " -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE:String=Release -DINSTALL_MODULES=OFF -DGENERATE_HOSTKEY=OFF -DMERGE_LISTEN_CONFIG=OFF"
-
-SYSTEMD_PACKAGES = "${PN}"
-SYSTEMD_SERVICE:${PN} = "netopeer2-serverd.service"
-SYSTEMD_AUTO_ENABLE:${PN} = "disable"
-
-do_install:append () {
-    install -d ${D}${sysconfdir}/netopeer2/scripts
-    install -o root -g root ${S}/scripts/setup.sh ${D}${sysconfdir}/netopeer2/scripts/setup.sh
-    install -o root -g root ${S}/scripts/merge_hostkey.sh ${D}${sysconfdir}/netopeer2/scripts/merge_hostkey.sh
-    install -o root -g root ${S}/scripts/merge_config.sh ${D}${sysconfdir}/netopeer2/scripts/merge_config.sh
-    install -d ${D}${sysconfdir}/netopeer2
-    install -d ${D}${sysconfdir}/init.d
-    if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
-        install -m 0755 ${WORKDIR}/netopeer2-server ${D}${sysconfdir}/init.d/
-    fi
-    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
-        install -d ${D}${systemd_system_unitdir}
-        install -m 0644 ${WORKDIR}/netopeer2-serverd.service ${D}${systemd_system_unitdir}
-    fi
-}
diff --git a/meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server_git.bbappend b/meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server_git.bbappend
deleted file mode 100644
index f8a9febe..00000000
--- a/meta-arago-extras/recipes-sysrepo/netopeer2-server/netopeer2-server_git.bbappend
+++ /dev/null
@@ -1,5 +0,0 @@ 
-FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
-
-SRC_URI += "file://0001-Add-EST-Yang-Models.patch"
-
-FILES:${PN} += "/usr/share/yang* /usr/share/netopeer2/* /usr/lib/sysrepo-plugind/*"