diff mbox series

[meta-oe] boardid: add recipe

Message ID 20260919101028.2828097-1-joaohf@gmail.com
State Under Review
Headers show
Series [meta-oe] boardid: add recipe | expand

Commit Message

João Henrique Ferreira de Freitas Sept. 19, 2026, 10:10 a.m. UTC 
Signed-off-by: João Henrique Ferreira de Freitas <joaohf@gmail.com>
---
 .../boardid/boardid_1.15.0.bb                 | 28 +++++++++++++++++++
 1 file changed, 28 insertions(+)
 create mode 100644 meta-oe/recipes-extended/boardid/boardid_1.15.0.bb

Comments

Ross Burton Sept. 19, 2026, 3:14 p.m. UTC | #1 
On 19 Sep 2026, at 11:10, João Henrique Ferreira de Freitas via lists.openembedded.org <joaohf=gmail.com@lists.openembedded.org> wrote:
> +SRC_URI = "git://github.com/nerves-project/boardid/;protocol=https;branch=main"

Pass tag=v${PV} too here, so that the SRCREV is validated against the tag name.

> +PV = "1.15.0"

This is the default, as the version in the filename sets PV.  You can remove this.

> +do_configure () {
> + :
> +}

Remove, the default will try to do a clean if needed.

> +do_compile () {
> + oe_runmake
> +}

This is the default, so you can remove this too.

Cheers,
Ross
diff mbox series

Patch

diff --git a/meta-oe/recipes-extended/boardid/boardid_1.15.0.bb b/meta-oe/recipes-extended/boardid/boardid_1.15.0.bb
new file mode 100644
index 0000000000..8e88ec9371
--- /dev/null
+++ b/meta-oe/recipes-extended/boardid/boardid_1.15.0.bb
@@ -0,0 +1,28 @@ 
+SUMMARY = "Print out a platform-specific board serial number"
+DESCRIPTION = "This program looks up a device-specific serial number and prints it. \
+The original use was to provide some non-changing and unique material for dynamically \
+creating device names on a local LAN. There are implementation specific boards as well \
+generic mechanisms for getting serial number."
+HOMEPAGE = "https://github.com/nerves-project/boardid"
+LICENSE = "Apache-2.0 AND CC-BY-4.0 AND CC0-1.0"
+LIC_FILES_CHKSUM = "file://LICENSES/Apache-2.0.txt;md5=c846ebb396f8b174b10ded4771514fcc \
+                    file://LICENSES/CC0-1.0.txt;md5=65d3616852dbf7b1a6d4b53b00626032 \
+                    file://LICENSES/CC-BY-4.0.txt;md5=9b33bbd06fb58995fb0e299cd38d1838"
+
+SRC_URI = "git://github.com/nerves-project/boardid/;protocol=https;branch=main"
+
+PV = "1.15.0"
+SRCREV = "2ccf22a8be22d7597e16fb225c1173876674f7a4"
+
+do_configure () {
+	:
+}
+
+do_compile () {
+	oe_runmake
+}
+
+do_install () {
+        install -d ${D}${bindir}
+        install -m 0755 ${S}/boardid ${D}${bindir}
+}