diff mbox series

[meta-oe,2/2] vkmark: add recipe for Vulkan graphics benchmark

Message ID 20260626113322.232336-2-ashwin.prabhakar@oss.qualcomm.com
State New
Headers show
Series [meta-oe,1/2] assimp: Add new recipe for Open Asset Import Library (Assimp) | expand

Commit Message

Ashwin Prabhakar June 26, 2026, 11:33 a.m. UTC 
From: Ashwin Prabhakar <ashwin.prabhakar@qti.qualcomm.com>

Add an initial recipe for vkmark to enable Vulkan performance testing.
This tool allows for benchmarking various Vulkan rendering scenes and
can be used to validate graphics drivers on target hardware.

Signed-off-by: Ashwin Prabhakar <ashwin.prabhakar@qti.qualcomm.com>

vkmark: fix build parse errors by making XCB support conditional

The current default PACKAGECONFIG explicitly enforces 'xcb'.
This causes build failures on distributions (like Yoe) that
lack 'x11' in their DISTRO_FEATURES, as 'libxcb' and
'xcb-util-wm' are skipped during parsing.

Fix this by dynamically adding 'xcb' to PACKAGECONFIG only
when 'x11' is present in DISTRO_FEATURES.

Signed-off-by: Ashwin Prabhakar <ashwin.prabhakar@qti.qualcomm.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
(cherry picked from commit f58670ca9a9e85e7f7a37f3155f4ce96fd64a4d2)
---
 .../recipes-benchmark/vkmark/vkmark_git.bb    | 31 +++++++++++++++++++
 1 file changed, 31 insertions(+)
 create mode 100644 meta-oe/recipes-benchmark/vkmark/vkmark_git.bb
diff mbox series

Patch

diff --git a/meta-oe/recipes-benchmark/vkmark/vkmark_git.bb b/meta-oe/recipes-benchmark/vkmark/vkmark_git.bb
new file mode 100644
index 0000000000..906ba85216
--- /dev/null
+++ b/meta-oe/recipes-benchmark/vkmark/vkmark_git.bb
@@ -0,0 +1,31 @@ 
+SUMMARY = "Vulkan benchmark"
+DESCRIPTION = "vkmark is an extensible Vulkan benchmarking suite with targeted, configurable scenes."
+HOMEPAGE = "https://github.com/vkmark/vkmark"
+
+LICENSE = "LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = "file://COPYING-LGPL2.1;md5=4fbd65380cdd255951079008b364516c"
+
+SRC_URI = "git://github.com/vkmark/vkmark.git;protocol=https;branch=master"
+SRCREV = "83a128d65b1adddfacb4fa2e555a7e90817a7266"
+
+PV = "2025.01+git${SRCPV}"
+
+inherit meson pkgconfig
+
+DEPENDS = " \
+    assimp \
+    glm \
+    vulkan-loader \
+"
+
+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'xcb', '', d)} wayland kms"
+
+PACKAGECONFIG[xcb] = "-Dxcb=true,-Dxcb=false,libxcb xcb-util-wm"
+PACKAGECONFIG[wayland] = "-Dwayland=true,-Dwayland=false,wayland wayland-native wayland-protocols"
+PACKAGECONFIG[kms] = "-Dkms=true,-Dkms=false,libdrm virtual/libgbm"
+
+FILES:${PN} += " \
+    ${libdir}/vkmark/*.so \
+    ${datadir}/vkmark \
+    ${mandir}/man1/vkmark.1* \
+"