diff mbox series

[meta-oe,1/3] thermald: import from meta-intel

Message ID 20260219112944.1555772-1-anuj.mittal@oss.qualcomm.com
State New
Headers show
Series [meta-oe,1/3] thermald: import from meta-intel | expand

Commit Message

Anuj Mittal Feb. 19, 2026, 11:29 a.m. UTC 
From: Anuj Mittal <anuj.mittal@oss.qualcomm.com>

thermald now supports ARM platforms [1], so move it out of meta-intel
to allow broader reuse.

This version remains compatible only with x86 but a future recipe
upgrade should fix COMPATIBLE_MACHINE.

[1] thermal_daemon 1931a12e7e ("Add ARM backend and enable ARM platform detection")

Signed-off-by: Anuj Mittal <anuj.mittal@oss.qualcomm.com>
---
 .../recipes-bsp/thermald/thermald_2.5.10.bb   | 43 +++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 meta-oe/recipes-bsp/thermald/thermald_2.5.10.bb
diff mbox series

Patch

diff --git a/meta-oe/recipes-bsp/thermald/thermald_2.5.10.bb b/meta-oe/recipes-bsp/thermald/thermald_2.5.10.bb
new file mode 100644
index 0000000000..6310602813
--- /dev/null
+++ b/meta-oe/recipes-bsp/thermald/thermald_2.5.10.bb
@@ -0,0 +1,43 @@ 
+SUMMARY = "Linux thermal daemon"
+
+DESCRIPTION = "Thermal Daemon is a Linux daemon used to prevent the \
+overheating of platforms. This daemon monitors temperature and applies \
+compensation using available cooling methods."
+
+HOMEPAGE = "https://github.com/01org/thermal_daemon"
+
+DEPENDS = "dbus dbus-glib dbus-glib-native libxml2 glib-2.0 glib-2.0-native upower libevdev"
+DEPENDS += "autoconf-archive-native"
+
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ea8831610e926e2e469075b52bf08848"
+
+SRC_URI = "git://github.com/intel/thermal_daemon/;branch=master;protocol=https \
+           "
+
+SRCREV = "88369b42ec523787081b9bf8811b364e2a3d5f2d"
+
+inherit pkgconfig autotools systemd gtk-doc
+
+# gtkdocsize runs before autotools do_configure and it copies gtk-doc.m4 and fails
+# to copy becuase there is no m4 dir yet.
+do_configure:prepend () {
+	mkdir -p ${S}/m4
+}
+
+EXTRA_OECONF = " \
+                 --with-systemdsystemunitdir=${systemd_system_unitdir} \
+                 "
+
+FILES:${PN} += "${datadir}/dbus-1"
+
+SYSTEMD_SERVICE:${PN} = "thermald.service"
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
+
+CONFFILES:${PN} = " \
+                   ${sysconfdir}/thermald/thermal-conf.xml \
+                   ${sysconfdir}/thermald/thermal-cpu-cdev-order.xml \
+                  "
+
+UPSTREAM_CHECK_URI = "https://github.com/01org/thermal_daemon/releases"