diff mbox series

[meta-oe,2/3] mailcap: add recipe

Message ID 20260131215636.2633863-3-skandigraun@gmail.com
State New
Headers show
Series Update and split mime-support | expand

Commit Message

Gyorgy Sarvari Jan. 31, 2026, 9:56 p.m. UTC 
This recipe is one of the successors of the mime-support, which
provided mailcap and mime.types files. This recipe contains
only the mailcap portion.

Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com>
---
 .../mime-support/mailcap_3.75.bb              | 54 +++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 meta-oe/recipes-support/mime-support/mailcap_3.75.bb
diff mbox series

Patch

diff --git a/meta-oe/recipes-support/mime-support/mailcap_3.75.bb b/meta-oe/recipes-support/mime-support/mailcap_3.75.bb
new file mode 100644
index 0000000000..6dc1fb3f8a
--- /dev/null
+++ b/meta-oe/recipes-support/mime-support/mailcap_3.75.bb
@@ -0,0 +1,54 @@ 
+SECTION = "base"
+SUMMARY = "MIME files 'mailcap', and support programs"
+LICENSE = "PD & Bellcore"
+LICENSE:${PN} = "PD"
+# mailcap.man's license is Bellcore
+LICENSE:${PN}-doc = "PD & Bellcore"
+LIC_FILES_CHKSUM = "file://debian/copyright;md5=881b8546ad4d18ee8d55d42c93cda0b6"
+
+DEPENDS = "file"
+RDEPENDS:${PN} = "perl"
+RRECOMMENDS:${PN} = "file"
+
+SRC_URI = "${DEBIAN_MIRROR}/main/m/${BPN}/${BPN}_${PV}.tar.xz"
+SRC_URI[sha256sum] = "44876c7241693ab32de57e799052b19a575ae0e27e85380537225708f562738f"
+S = "${UNPACKDIR}/work"
+
+FILES:${PN} += " ${libdir}/mime"
+
+docdir:append = "/${BPN}"
+
+do_install () {
+    install -d ${D}${sysconfdir}
+    install -d ${D}${libdir}/mime/packages
+    install -d ${D}${docdir}
+    install -d ${D}${sbindir}
+    install -d ${D}${bindir}
+    install -d ${D}${mandir}/man1
+    install -d ${D}${mandir}/man5
+    install -d ${D}${mandir}/man8
+    install -m 644 mailcap            ${D}${libdir}/mime
+    install -m 644 mailcap.order      ${D}${sysconfdir}/
+    install -m 644 mailcap.man        ${D}${mandir}/man5/mailcap.5
+    install -m 644 mailcap.order.man  ${D}${mandir}/man5/mailcap.order.5
+    install -m 755 update-mime        ${D}${sbindir}/
+    install -m 644 update-mime.man    ${D}${mandir}/man8/update-mime.8
+    install -m 755 run-mailcap        ${D}${bindir}/
+    install -m 644 run-mailcap.man    ${D}${mandir}/man1/run-mailcap.1
+    install -m 644 debian/changelog   ${D}${docdir}
+    install -m 644 debian/copyright   ${D}${docdir}
+    install -m 755 debian-view        ${D}${libdir}/mime/
+    install -m 644 mailcap.entries    ${D}${libdir}/mime/packages/mailcap
+    cd ${D}${mandir}; gzip -9fv */*
+    cd ${D}${docdir}; gzip -9v changelog
+    cd ${D}${bindir}; ln -s run-mailcap see
+    cd ${D}${bindir}; ln -s run-mailcap edit
+    cd ${D}${bindir}; ln -s run-mailcap compose
+    cd ${D}${bindir}; ln -s run-mailcap print
+    cd ${D}${mandir}/man1; ln -s run-mailcap.1.gz see.1.gz
+    cd ${D}${mandir}/man1; ln -s run-mailcap.1.gz edit.1.gz
+    cd ${D}${mandir}/man1; ln -s run-mailcap.1.gz compose.1.gz
+    cd ${D}${mandir}/man1; ln -s run-mailcap.1.gz print.1.gz
+}
+
+INHIBIT_DEFAULT_DEPS = "1"