diff mbox series

[meta-oe,scarthgap,v2,1/5] can-utils: Upgrade 2023.03 -> 2025.01

Message ID 20250418115141.150272-2-alb3rt0.m3rciai@gmail.com
State New
Headers show
Series can-utils: Upgrade 2023.03 -> 2025.01 | expand

Commit Message

Alberto Merciai April 18, 2025, 11:51 a.m. UTC 
From: Ricardo Simoes <ricardo.simoes@pt.bosch.com>

Changelog: https://github.com/linux-can/can-utils/releases/tag/v2025.01

Signed-off-by: Ricardo Simoes <ricardo.simoes@pt.bosch.com>
Signed-off-by: Mark Jonas <mark.jonas@de.bosch.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 .../socketcan/can-utils_2025.01.bb            | 68 +++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 meta-oe/recipes-extended/socketcan/can-utils_2025.01.bb
diff mbox series

Patch

diff --git a/meta-oe/recipes-extended/socketcan/can-utils_2025.01.bb b/meta-oe/recipes-extended/socketcan/can-utils_2025.01.bb
new file mode 100644
index 0000000000..cad41944ec
--- /dev/null
+++ b/meta-oe/recipes-extended/socketcan/can-utils_2025.01.bb
@@ -0,0 +1,68 @@ 
+SUMMARY = "Linux CAN network development utilities"
+LICENSE = "GPL-2.0-only & BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://include/linux/can.h;endline=44;md5=a9e1169c6c9a114a61329e99f86fdd31"
+
+DEPENDS = "libsocketcan"
+
+SRC_URI = "git://github.com/linux-can/${BPN}.git;protocol=https;branch=master"
+
+SRCREV = "01083a64ebf28cc716efe2d2fd51c141042ae34b"
+
+S = "${WORKDIR}/git"
+
+inherit cmake pkgconfig update-alternatives
+
+PACKAGES =+ " \
+    ${PN}-access \
+    ${PN}-cantest \
+    ${PN}-isobusfs \
+    ${PN}-isobusfs-dev \
+    ${PN}-isotp \
+    ${PN}-j1939 \
+    ${PN}-log \
+    ${PN}-slcan \
+"
+
+FILES:${PN}-access = " \
+    ${bindir}/cangw \
+    ${bindir}/canlogserver \
+    ${bindir}/bcmserver \
+    ${bindir}/socketcand \
+    ${bindir}/cannelloni \
+"
+
+FILES:${PN}-cantest = " \
+    ${bindir}/canbusload \
+    ${bindir}/can-calc-bit-timing \
+    ${bindir}/canfdtest \
+"
+
+FILES:${PN}-isobusfs = " \
+    ${bindir}/isobusfs-cli \
+    ${bindir}/isobusfs-srv \
+    ${libdir}/libisobusfs.so \
+"
+
+FILES:${PN}-isobusfs-dev = " \
+    ${includedir}/isobusfs* \
+"
+
+FILES:${PN}-isotp = "${bindir}/isotp*"
+
+FILES:${PN}-j1939 = " \
+    ${bindir}/j* \
+    ${bindir}/testj1939 \
+"
+
+FILES:${PN}-log = "${bindir}/*log*"
+
+FILES:${PN}-slcan = "${bindir}/slcan*"
+
+ALTERNATIVE:${PN} = "candump cansend cansequence"
+ALTERNATIVE_LINK_NAME[candump] = "${bindir}/candump"
+ALTERNATIVE_LINK_NAME[cansend] = "${bindir}/cansend"
+ALTERNATIVE_LINK_NAME[cansequence] = "${bindir}/cansequence"
+
+# busybox ip fails to configure can interfaces, so we need iproute2 to do so.
+# See details in http://www.armadeus.com/wiki/index.php?title=CAN_bus_Linux_driver.
+RRECOMMENDS:${PN} += "iproute2-ip"