add recipes: canopenterm 1.0.8, pocketpy 2.0.2

CANopenTerm is a versatile software tool to analyse and configure CANopen
devices.  It extends its capabilities to support other CAN CC protocols,
including SAE J1939 and OBD-II.

pocketpy is a portable Python 3.x interpreter in modern C.  CANopenTerm
depends on it.

Signed-off-by: Michael Fitzmayer <mail@michael-fitzmayer.de>
---
 .../pocketpy/pocketpy_2.0.2.bb                | 25 +++++++++++++++++++
 .../canopenterm/canopenterm_1.0.8.bb          | 23 +++++++++++++++++
 2 files changed, 48 insertions(+)
 create mode 100644 meta-oe/recipes-devtools/pocketpy/pocketpy_2.0.2.bb
 create mode 100644 meta-oe/recipes-extended/canopenterm/canopenterm_1.0.8.bb

On Thu, Nov 21, 2024 at 11:08 AM Michael Fitzmayer via
lists.openembedded.org
<mail=michael-fitzmayer.de@lists.openembedded.org> wrote:
>
> CANopenTerm is a versatile software tool to analyse and configure CANopen
> devices.  It extends its capabilities to support other CAN CC protocols,
> including SAE J1939 and OBD-II.
>
> pocketpy is a portable Python 3.x interpreter in modern C.  CANopenTerm
> depends on it.
>
> Signed-off-by: Michael Fitzmayer <mail@michael-fitzmayer.de>
> ---
>  .../pocketpy/pocketpy_2.0.2.bb                | 25 +++++++++++++++++++
>  .../canopenterm/canopenterm_1.0.8.bb          | 23 +++++++++++++++++
>  2 files changed, 48 insertions(+)
>  create mode 100644 meta-oe/recipes-devtools/pocketpy/pocketpy_2.0.2.bb
>  create mode 100644 meta-oe/recipes-extended/canopenterm/canopenterm_1.0.8.bb
>
> diff --git a/meta-oe/recipes-devtools/pocketpy/pocketpy_2.0.2.bb b/meta-oe/recipes-devtools/pocketpy/pocketpy_2.0.2.bb
> new file mode 100644
> index 000000000..4bbef91d5
> --- /dev/null
> +++ b/meta-oe/recipes-devtools/pocketpy/pocketpy_2.0.2.bb
> @@ -0,0 +1,25 @@
> +SUMMARY     = "pocketpy"

This seems too terse, infact the DESCRIPTION below is apt for summary.

> +DESCRIPTION = "A Portable Python 3.x Interpreter in Modern C"
> +HOMEPAGE    = "https://pocketpy.dev/"
> +BUGTRACKER  = "https://github.com/pocketpy/pocketpy/issues"
> +
> +LICENSE = "MIT"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=8cdfa87bc5e09bc07f8cf64135026d91"
> +
> +SRC_URI = "git://github.com/pocketpy/pocketpy.git;protocol=https;branch=main;tag=v${PV}"

lets not use tag here, they may not work when the network is disabled
since they act as floating labels, please set
SRCREV instead.

> +S       = "${WORKDIR}/git"

additional space after S are unusual, just use one space.

> +
> +inherit cmake
> +
> +do_install() {
> +    install -d ${D}${libdir}
> +    install -m 0644 ${B}/libpocketpy.so ${D}${libdir}/
> +    install -d ${D}${includedir}/pocketpy
> +    cp -r ${S}/include/* ${D}${includedir}/pocketpy/
> +}
> +
> +PACKAGES = "${PN} ${PN}-dev ${PN}-dbg"

It seems unnecessary to redefine PACKAGES here. Just remove it.

> +
> +FILES:${PN}      = "${libdir}/libpocketpy.so"
> +FILES:${PN}-dev  = "${includedir}/pocketpy"
> +FILES:${PN}-dbg += "${libdir}/.debug/libpocketpy.so"
> diff --git a/meta-oe/recipes-extended/canopenterm/canopenterm_1.0.8.bb b/meta-oe/recipes-extended/canopenterm/canopenterm_1.0.8.bb
> new file mode 100644
> index 000000000..82295303d
> --- /dev/null
> +++ b/meta-oe/recipes-extended/canopenterm/canopenterm_1.0.8.bb
> @@ -0,0 +1,23 @@
> +
> +SUMMARY     = "CANopenTerm"

Too terse like recipe above

> +DESCRIPTION = "A versatile software tool to analyse and configure CANopen devices"
> +HOMEPAGE    = "https://canopenterm.de"
> +BUGTRACKER  = "https://github.com/CANopenTerm/CANopenTerm/issues"
> +
> +LICENSE = "MIT"
> +LIC_FILES_CHKSUM = "file://LICENSE.md;md5=10e84ea70e8c3a1fbc462f5424806474"
> +
> +DEPENDS = "libinih libsdl2 lua libsocketcan pocketpy readline"
> +
> +SRC_URI = "git://github.com/CANopenTerm/CANopenTerm.git;protocol=https;branch=main;tag=v${PV}"

Hmm, same comment as above

> +S       = "${WORKDIR}/git"
> +
remove additional spaces

> +inherit cmake
> +
> +EXTRA_OECMAKE += "-DBUILD_YOCTO=ON"
> +
> +FILES:${PN} += "/usr/bin/CANopenTerm \
> +                /usr/share/CANopenTerm \
> +               "

Use ${bindir} and ${datadir} variables instead of hardcoding /usr/bin
and /usr/share

> +
> +RDEPENDS:${PN} = "libinih libsdl2 lua libsocketcan pocketpy readline"
> --
> 2.39.5
>
>
> -=-=-=-=-=-=-=-=-=-=-=-
> Links: You receive all messages sent to this group.
> View/Reply Online (#113975): https://lists.openembedded.org/g/openembedded-devel/message/113975
> Mute This Topic: https://lists.openembedded.org/mt/109709776/1997914
> Group Owner: openembedded-devel+owner@lists.openembedded.org
> Unsubscribe: https://lists.openembedded.org/g/openembedded-devel/unsub [raj.khem@gmail.com]
> -=-=-=-=-=-=-=-=-=-=-=-
>