diff mbox series

[meta-gnome] gnome-control-center: add recipe

Message ID 20230117072716.63391-1-f_l_k@t-online.de
State New
Headers show
Series [meta-gnome] gnome-control-center: add recipe | expand

Commit Message

Markus Volk Jan. 17, 2023, 7:27 a.m. UTC 
Add a recipe for gnome-remote-desktop and a corresponding PACKAGECONFIG for
gnome-control-center from where it can be enabled/disabled, if available.

It is not enabled by default because it has a dependency on tpm2-tss and thus
adds a layer dependency on meta-security/meta-tpm.

Signed-off-by: Markus Volk <f_l_k@t-online.de>
---
 .../gnome-control-center_43.2.bb              |  1 +
 .../gnome-remote-desktop_43.3.bb              | 38 +++++++++++++++++++
 2 files changed, 39 insertions(+)
 create mode 100644 meta-gnome/recipes-gnome/gnome-remote-desktop/gnome-remote-desktop_43.3.bb
diff mbox series

Patch

diff --git a/meta-gnome/recipes-gnome/gnome-control-center/gnome-control-center_43.2.bb b/meta-gnome/recipes-gnome/gnome-control-center/gnome-control-center_43.2.bb
index 830f3ec68..16a400c5c 100644
--- a/meta-gnome/recipes-gnome/gnome-control-center/gnome-control-center_43.2.bb
+++ b/meta-gnome/recipes-gnome/gnome-control-center/gnome-control-center_43.2.bb
@@ -42,6 +42,7 @@  SRC_URI[archive.sha256sum] = "d7f256aba80a92c727b329fd01c8602da4b78f0fddaec93fcd
 PACKAGECONFIG ??= "ibus ${@bb.utils.filter('DISTRO_FEATURES', 'wayland', d)}"
 PACKAGECONFIG[ibus] = "-Dibus=true, -Dibus=false, ibus"
 PACKAGECONFIG[wayland] = "-Dwayland=true, -Dwayland=false, wayland"
+PACKAGECONFIG[remote-desktop] = ",,,gnome-remote-desktop"
 
 EXTRA_OEMESON = " \
     -Doe_sysroot=${STAGING_DIR_HOST} \
diff --git a/meta-gnome/recipes-gnome/gnome-remote-desktop/gnome-remote-desktop_43.3.bb b/meta-gnome/recipes-gnome/gnome-remote-desktop/gnome-remote-desktop_43.3.bb
new file mode 100644
index 000000000..5d1a85d5f
--- /dev/null
+++ b/meta-gnome/recipes-gnome/gnome-remote-desktop/gnome-remote-desktop_43.3.bb
@@ -0,0 +1,38 @@ 
+SUMMARY = "Remote desktop daemon for GNOME using pipewire."
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+GNOMEBASEBUILDCLASS = "meson"
+
+inherit gnomebase gettext gsettings features_check
+
+REQUIRED_DISTRO_FEATURES = "opengl"
+
+SRC_URI[archive.sha256sum] = "11d451d1fde44f1809ebf61aff4bea5f9ef4fdc02359a89647f6e9e7d45429ac"
+
+DEPENDS = " \
+    asciidoc-native \
+    libdrm \
+    libepoxy \
+    cairo \
+    glib-2.0 \
+    pipewire \
+    libnotify \
+    libsecret \
+    nv-codec-headers \
+    tpm2-tss \
+"
+
+PACKAGECONFIG ??= " \
+    vnc \
+    rdp \
+    ${@bb.utils.contains('LICENSE_FLAGS_ACCEPTED', 'commercial', 'fdk_aac', '', d)} \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
+"
+
+PACKAGECONFIG[vnc] = "-Dvnc=true,-Dvnc=false,libvncserver"
+PACKAGECONFIG[rdp] = "-Drdp=true,-Drdp=false,freerdp fuse3 libxkbcommon"
+PACKAGECONFIG[fdk_aac] = "-Dfdk_aac=true,-Dfdk_aac=false,fdk-aac"
+PACKAGECONFIG[systemd] = "-Dsystemd=true,-Dsystemd=false,systemd"
+
+FILES:${PN} += "${systemd_user_unitdir}"