diff --git a/meta-oe/recipes-dbs/sqlpp23/sqlpp23_0.69.bb b/meta-oe/recipes-dbs/sqlpp23/sqlpp23_0.69.bb
new file mode 100644
index 0000000000..ad0d4c4e5b
--- /dev/null
+++ b/meta-oe/recipes-dbs/sqlpp23/sqlpp23_0.69.bb
@@ -0,0 +1,38 @@
+HOMEPAGE = "https://github.com/rbock/sqlpp23"
+SUMMARY = "A type safe SQL library for C++"
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=fe3abf7ac4f19dc926a8ab383003aaa7"
+
+SRC_URI = "git://github.com/rbock/sqlpp23;protocol=https;branch=main;tag=${PV}"
+
+SRCREV = "1c47ff3c7c3542aa6091266be77122c7ced031e8"
+
+inherit cmake ptest
+
+do_install:append() {
+    install -m 0755 ${S}/scripts/sqlpp23-ddl2cpp ${D}${bindir}
+}
+
+PACKAGECONFIG ??= " \
+    sqlite3 \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'ptest', d)} \
+"
+
+PACKAGECONFIG[sqlite3] = "-DBUILD_SQLITE3_CONNECTOR=ON,-DBUILD_SQLITE3_CONNECTOR=OFF,sqlite3,"
+PACKAGECONFIG[mysql] = "-DBUILD_MYSQL_CONNECTOR=ON,-DBUILD_MYSQL_CONNECTOR=OFF,mariadb,"
+PACKAGECONFIG[mariadb] = "-DBUILD_MARIADB_CONNECTOR=ON,-DBUILD_MARIADB_CONNECTOR=OFF,mariadb,"
+PACKAGECONFIG[postgresql] = "-DBUILD_POSTGRESQL_CONNECTOR=ON,-DBUILD_POSTGRESQL_CONNECTOR=OFF,postgresql,"
+PACKAGECONFIG[sqlchiper] = "-DBUILD_SQLCIPHER_CONNECTOR=ON,-DBUILD_SQLCIPHER_CONNECTOR=OFF,,"
+PACKAGECONFIG[ptest] = "-DENABLE_TESTING=ON,-DENABLE_TESTING=OFF,,"
+
+# sqlpp23-ddl2cpp is staged in bindir, and is needed for code generation in downstream programs.
+# Shipped only in the -tools package
+PACKAGES =+ "${PN}-tools"
+RDEPENDS:${PN}-tools = "python3"
+FILES:${PN}-tools = "${bindir}/sqlpp23-ddl2cpp"
+SYSROOT_DIRS:append = " ${bindir}"
+
+BBCLASSEXTEND = "native nativesdk"
+
+# sqlpp23 is a header-only C++ library, so the main package will be empty.
+ALLOW_EMPTY:${PN} = "1"